/*----------------------------------------------------------------------------
    S.M.E.L.T. : Small Musically Expressive Laptop Toolkit

    Copyright (c) 2007 Rebecca Fiebrink and Ge Wang.  All rights reserved.
      http://smelt.cs.princeton.edu/
      http://soundlab.cs.princeton.edu/

    This program is free software; you can redistribute it and/or modify
    it under the terms of the GNU General Public License as published by
    the Free Software Foundation; either version 2 of the License, or
    (at your option) any later version.

    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License
    along with this program; if not, write to the Free Software
    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
    U.S.A.
-----------------------------------------------------------------------------*/

//-----------------------------------------------------------------------------
// name: SmackingMusic.ck
// desc: Sudden Motion Sensor (SMS)-based smack detector
//
// author: Rebecca Fiebrink
//
// requires: SMS-enabled powerbook or macbook running OS X (10.4.8 or higher)
//
// to run (in command line chuck):
//     %> chuck SmackingMusic.ck
//     (note: works best when started with laptop on stationary hard surface)
//
// to run (in miniAudicle):
//     (don't)
//-----------------------------------------------------------------------------

// smack detection threshold (less -> more sensitive)
15 => int threshold;
// pol rate
.01::second => dur poll_rate;
// recover time (after smack detection)
.10::second => dur recover_time;

// instantiate a HidIn object
// instantiate a HidIn object
HidIn hi;
HidMsg msg;
    
// open tilt sensor
if( !hi.openTiltSensor() )
{
    <<< "tilt sensor unavailable", "" >>>;
    me.exit();
}

// "go"
<<< "ready to smack", "" >>>;

// remember
HidMsg last;
// initialize
hi.read( 9, 0, last );

// feature: commands to send to the shell
[   "banner S",
    "banner M",
    "banner A",
    "banner C",
    "banner K",
    "banner I",
    "banner N",
    "banner G",
    "banner \" \"",
    "banner M",
    "banner U",
    "banner S",
    "banner I",
    "banner C"
] @=> string cmds[];

// infinite event loop
while( true )
{
    // poll the tilt sensor, expect to get back 3 element array of ints
    hi.read( 9, 0, msg );
    
    // compute difference
    (Math.abs(msg.x - last.x) + Math.abs(msg.y - last.y) + Math.abs(msg.z - last.z)) => int diff;

    // check threshold
    if (diff > threshold)
    {
        // smack detected!
        Std.system( cmds[Std.rand2(0, cmds.cap()-1)] );

		 // recover
        recover_time => now;
    }
    else
    {
        // uncomment the following to dynamically calibrate the smack sensor
        // msg.x => last.x;             
        // msg.y => last.y;
        // msg.z => last.z;

        poll_rate => now;
    }
}